| 首页 | | | 资讯中心 | | | 贸金人物 | | | 政策法规 | | | 考试培训 | | | 供求信息 | | | 会议展览 | | | 汽车金融 | | | O2O实践 | | | CFO商学院 | | | 纺织服装 | | | 轻工工艺 | | | 五矿化工 | ||
贸易 |
| | 贸易税政 | | | 供 应 链 | | | 通关质检 | | | 物流金融 | | | 标准认证 | | | 贸易风险 | | | 贸金百科 | | | 贸易知识 | | | 中小企业 | | | 食品土畜 | | | 机械电子 | | | 医药保健 | ||
金融 |
| | 银行产品 | | | 贸易融资 | | | 财资管理 | | | 国际结算 | | | 外汇金融 | | | 信用保险 | | | 期货金融 | | | 信托投资 | | | 股票理财 | | | 承包劳务 | | | 外商投资 | | | 综合行业 | ||
推荐 |
| | 财资管理 | | | 交易银行 | | | 汽车金融 | | | 贸易投资 | | | 消费金融 | | | 自贸区通讯社 | | | 电子杂志 | | | 电子周刊 | ||||||||||
把会计常用的Excel公式进行一次整理，共16个，希望对做会计工作的同学们有用。
1 完成率公式
如下图所示，要求根据B的实际和C列的预算数，计算完成率。
公示：E2
=IF(C3<0,2-B3/C3,B3/C3)
2 同比增长率公式
如下图所示，B列是本年累计，C列是去年同期累计，要求计算同比增长率。
公示：E2
=(B2-C2)/IF(C2>0,C2,-C2)
3 金额大小写公式
=TEXT(LEFT(RMB(A2),LEN(RMB(A2))-3),"[>0][dbnum2]G/通用格式元;[<0]负[dbnum2]G/通用格式元;;")&TEXT(RIGHT(RMB(A2),2),"[dbnum2]0角0分;;整")
4 多条件判断公式
公式：C2
=IF(AND(A2<500,B2="未到期"),"补款","")
说明：两个条件同时成立用AND,任一个成立用OR函数。
5、单条件查找公式
公式1：C11
=VLOOKUP(B11,B3:F7,4,FALSE)
6 双向查找公式
公式：
=INDEX(C3:H7,MATCH(B10,B3:B7,0),MATCH(C10,C2:H2,0))
说明：利用MATCH函数查找位置，用INDEX函数取值
7 多条件查找公式
公式：C35
=Lookup(1,0/((B25:B30=C33)*(C25:C30=C34)),D25:D30)
8 单条件求和公式
公式：F2
=SUMIF(A:A,E2,C:C)
9 多条件求和公式
=Sumifs(c2:c7,a2:a7,a11,b2:b7,b11)
10 隔列求和公式
公式H3:
=SUMIF($A$2:$G$2,H$2,A3:G3)
如果没有标题，那只能用稍复杂的公式了。
=SUMPRODUCT((MOD(COLUMN(B3:G3),2)=0)*B3:G3)
11 两条查找相同公式
公式:B2
=COUNTIF(Sheet15!A:A,A2)
说明：如果返回值大于0说明在另一个表中存在，0则不存在。
12 两表数据多条件核对
如下图所示，要求核对两表中同一产品同一型号的数量差异，显示在D列。
公式：D10
=SUMPRODUCT(($A$2:$A$6=A10)*($B$2:$B$6=B10)*$C$2:$C$6)-C10
13 个税计算
假如A2中是应税工资，则计算个税公式为：
=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)
14、会计科目截取公式
一级科目：
=LEFT(B3,FIND("-",B3)-2)
二级科目：
=MID(B3,FIND("-",B3)+2,FIND("-",B3&"-",FIND("-",B3)+1)-FIND("-",B3)-3)
三级科目：
=MID(B3,FIND("-",B3&"-",FIND("-",B3)+1)+2,100)
15 多表同一位置汇总公式
多个工作表如果格式完全相同，可以用sum函数的多表求和功能。
如下图所示，要求在汇总表里设置合计公式，汇总前19个工作表B列的和。
B2=SUM(Sheet1:Sheet19!B2)
16 中国式排名公式
公式:C12
=SUMPRODUCT(($D$4:$D$9>=D4)*(1/COUNTIF(D$4:D$9,D$4:D$9)))
文章来源：Excel精英培训微信公众号
